Team AAZ - Forum

Code : Tout sélectionner

Get-HotFix
control /name Microsoft.WindowsUpdate /page History
appwiz.cpl
wmic qfe list

Code : Tout sélectionner

@set ver=1.1 du 27-06-2025
@echo off

rem == Gérer les caractères spéciaux en UTF-8 ==
chcp 65001 >nul
color b0

mkdir temp 2>nul

echo ------------------------------------------------------------------------------------------
echo ================ del_SSU_modif_permanent_Script version %ver% ================
echo ------------------------------------------------------------------------------------------
setlocal enabledelayedexpansion

:askPath
REM Demande à l'utilisateur de spécifier le dossier de montage
set /p "mountDir=Entrez le chemin du dossier de montage : "

REM Vérifie si le chemin est "C:" sans antislash
if /i "%mountDir%"=="C:" (
    echo Erreur : le chemin "C:" est incomplet. Il manque un "\". Utilisez "C:\" si c'est une image Online.
    echo Appuyez sur une touche pour réessayer ou fermez la fenêtre pour quitter.
    pause >nul
    echo.
    goto askPath
)

REM Vérifie si le dossier de montage existe
if not exist "%mountDir%" (
    echo Le dossier de montage "%mountDir%" n'existe pas.
    echo Appuyez sur une touche pour réessayer ou fermez la fenêtre pour quitter.
    pause >nul
    echo.
    goto askPath
)

REM Chemin vers le dossier de Packages
set "packageDir=%mountDir%Windows\servicing\Packages"
if not exist "%packageDir%" (
    echo Le dossier "%packageDir%" n'existe pas.
    echo Appuyez sur une touche pour réessayer ou fermez la fenêtre pour quitter.
    pause >nul
    echo.
    goto askPath
)



REM Initialisation
set "files="
set "maxVer=0"
set "minVer=99999"
set "latestPkg="
set "oldestPkg="

REM Récupération des fichiers et extraction des versions
for %%f in ("%packageDir%\Package_for_ServicingStack*.mum") do (
    set "fname=%%~nxf"
    set "files=!files! %%~nxf"
    
    REM Extraire la version en fonction du séparateur (_ ou ~)
    set "verNum="
    set "str=!fname:Package_for_ServicingStack_=!"
    if "!str!"=="!fname!" (
        REM Pas de underscore, essayer avec tilde
        set "str=!fname:Package_for_ServicingStack~=!"
        REM Si toujours pas modifié, ignorer
        if "!str!"=="!fname!" (
            set "str="
        )
    )
    
    if defined str (
        set "verNum=!str:~0,4!"
        
        REM Vérifier si verNum est numérique
        for /f "delims=0123456789" %%a in ("!verNum!") do set "verNum="
        
        if defined verNum (
            REM Mise à jour du plus récent
            if !verNum! gtr !maxVer! (
                set "maxVer=!verNum!"
                set "latestPkg=!fname!"
            )
            REM Mise à jour du plus ancien
            if !verNum! lss !minVer! (
                set "minVer=!verNum!"
                set "oldestPkg=!fname!"
            )
        )
    )
)

echo ------------------------------------------------------------------------------------------
echo ================ Modification des SSU en "removable" pour leurs suppressions ================ 
echo ------------------------------------------------------------------------------------------

REM Cas particulier : si on détecte un package avec tilde 1220, forcer oldestPkg à celui-ci
for %%f in (!files!) do (
    echo %%f | findstr /i /c:"Package_for_ServicingStack~" >nul
    if !errorlevel! == 0 (
        set "oldestPkg=%%f"
        goto skipOldestCheck
    )
)
:skipOldestCheck

echo.
echo Package le plus ancien (conservé en permanent) : !oldestPkg!
echo Package le plus récent (conservé en permanent) : !latestPkg!
echo.

REM Modification des fichiers sauf les deux extrêmes
for %%f in (!files!) do (
    if /i not "%%f"=="!latestPkg!" if /i not "%%f"=="!oldestPkg!" (
        set "inputFile=%packageDir%\%%f"
        set "tempFile=!inputFile!.tmp"

        if exist "!inputFile!" (
            (
                for /f "usebackq delims=" %%a in ("!inputFile!") do (
                    setlocal enabledelayedexpansion
                    set "line=%%a"
                    set "line=!line:permanent=removable!"
                    echo !line!
                    endlocal
                )
            ) > "!tempFile!"

            move /y "!tempFile!" "!inputFile!" >nul
            echo Modifié : %%f
        )
    )
)

echo ------------------------------------------------------------------------------------------
echo ================ Suppression Ancien SSU modifié ================ 
echo ------------------------------------------------------------------------------------------

REM Définir la variable dismImageOption selon mountDir
if /i "%mountDir%"=="C:\" (
    set "dismImageOption=/Online"
) else (
    set "dismImageOption=/Image:%mountDir%"
)

REM Suppression sauf le plus ancien et le plus récent
for %%f in (!files!) do (
    if /i not "%%f"=="!latestPkg!" if /i not "%%f"=="!oldestPkg!" (
        set "pkgName=%%f"
        setlocal enabledelayedexpansion
        set "pkgName=!pkgName:.mum=!"
        dism /scratchdir:temp !dismImageOption! /Remove-Package /PackageName:!pkgName!
        endlocal
    )
)


echo ------------------------------------------------------------------------------------------
echo ================ Nettoyage fichiers sauvegarde de Windows Update via DISM ================
echo ------------------------------------------------------------------------------------------

dism !dismImageOption! /Cleanup-Image /StartComponentCleanup

rd /s /q temp 2>nul

pause
exit