suite à un travail récent sur mon pc pour récupérer de l'espace libre,
je vous fais profiter pour ceux qui ne connaissaient pas quelques astuces.
Analyser la taille dossier WinSxS
À partir d’une invite de commandes, tapez la commande suivante pour l’analyse:
Code : Tout sélectionner
Dism.exe /Online /Cleanup-Image /AnalyzeComponentStore
Sur cet exemple, il est recommandé de faire le nettoyage
Nettoyer le dossier WinSxS. A partir d’une invite de commandes, tapez la commande suivante:
Code : Tout sélectionner
Dism.exe /online /Cleanup-Image /StartComponentCleanup
Code : Tout sélectionner
Dism.exe /online /Cleanup-Image /StartComponentCleanup /ResetBase
Purger/vider le dossier C:\WINDOWS\Installer
c'est possible en faisant un fichier bat
avec ceci dedans
Code : Tout sélectionner
@echo off
rem Liste des packages msi/msp (c:\windows\installer)
setlocal ENABLEDELAYEDEXPANSION
set dircmd=/a
set tailletotale=0
set taillefichier=0
set windowsinstaller=%windir%\installer
set listemsimsp=%temp%\listmsimsp.txt
set fichiersuppression=.\deleteMSIMSP.cmd
REM Extrait de la base de registre les msi/msp que l'on trouve dans c:\windows\installer
reg query hklm\software\microsoft\windows\currentversion\installer /s|find /i "localpackage"|find /i "%windowsinstaller%">"%listemsimsp%"
REM Pour chaque fichier msi/msp de c:\windows\installer, on regarde s'il est reference dans la base de registre
echo pause > "%fichiersuppression%"
for %%m in ("%windowsinstaller%\*.msp" "%windowsinstaller%\*.msi") do (
find /I "%%m" "%listemsimsp%">NUL
if errorlevel 1 (
set /a taillefichier=%%~zm/1048576
set /a tailletotale=!tailletotale!+!taillefichier!
echo Fichier "%%m" !taillefichier! Mo introuvable dans "HKLM\...\installer"
echo del "%%m" >> "%fichiersuppression%"
)
)
echo pause >> "%fichiersuppression%"
echo Taille totale ^(approximative^): !tailletotale! Mo
pause
endlocal
Merci à Jérome du forum answers.microsoft.com